.NET Rant

Sven Groot wrote:


Depends on what you're doing. A few reflection calls won't make a different, but do it millions of times in a tight loop and you'll feel it.

Reflection is not just slower, it's orders of magnitude slower than a regular method call. This is perfectly normal because of the extra work it has to do. If you're really worried about it, use a dynamic method.

Each test will perform 1000000 iterations.

Compiled        00:00:00.3801251
Dynamic Method  00:00:00.3956237
Reflection 1    00:00:10.0621492
Reflection 2    00:00:12.1479894
Late Binding    00:00:22.9242498

Each test will perform 1000000 iterations.

Compiled        00:00:00.3749116
Dynamic Method  00:00:00.3929541
Reflection 1    00:00:08.9885750
Reflection 2    00:00:10.8800976
Late Binding    00:00:21.4694188

Imports System
Imports System.Diagnostics
Imports System.Reflection
Imports System.Reflection.Emit

Class Foo
  Private _bar As String

  Public Property Bar() As String
    Get
      Return _bar
    End Get
    Set(ByVal value As String)
      _bar = value
    End Set
  End Property
End Class

Module Module1
  Public Const kITER = 1000000

  Delegate Sub TestDelegate(ByVal arg As Foo, ByVal str As String)

  Function CreateMethod() As TestDelegate
    Dim args() As Type = {GetType(Foo), GetType(String)}
    Dim method As New DynamicMethod("Test", Nothing, args, GetType(Module1))
    Dim gen As ILGenerator = method.GetILGenerator()
    gen.Emit(OpCodes.Ldarg_0)
    gen.Emit(OpCodes.Ldarg_1)
    Dim m As MethodInfo = GetType(Foo).GetProperty("Bar").GetSetMethod()
    gen.EmitCall(OpCodes.Call, m, Nothing)
    gen.Emit(OpCodes.Ret)
    Return method.CreateDelegate(GetType(TestDelegate))
  End Function


  Sub Main()
    Dim i As Integer
    Dim f As New Foo
    Dim w As New Stopwatch

    Console.WriteLine("Each test will perform {0} iterations." & vbCrLf, kITER)

    Console.Write("Compiled" & vbTab)
    w.Start()
    For i = 1 To kITER
      f.Bar = i.ToString()
    Next
    w.Stop()
    Console.WriteLine(w.Elapsed)

    Console.Write("Dynamic Method" & vbTab)
    Dim test As TestDelegate = CreateMethod()
    w.Reset()
    w.Start()
    For i = 1 To kITER
      test(f, i.ToString())
    Next
    w.Stop()
    Console.WriteLine(w.Elapsed)

    Console.Write("Reflection 1" & vbTab)
    w.Reset()
    w.Start()
    Dim t As Type = f.GetType()
    Dim pi As PropertyInfo = t.GetProperty("Bar")
    For i = 1 To kITER
      pi.SetValue(f, i.ToString(), Nothing)
    Next
    w.Stop()
    Console.WriteLine(w.Elapsed)

    Console.Write("Reflection 2" & vbTab)
    w.Reset()
    w.Start()
    For i = 1 To kITER
      Dim t2 As Type = f.GetType()
      Dim pi2 As PropertyInfo = t2.GetProperty("Bar")
      pi2.SetValue(f, i.ToString(), Nothing)
    Next
    w.Stop()
    Console.WriteLine(w.Elapsed)

    Console.Write("Late Binding" & vbTab)
    Dim o As Object = f
    w.Reset()
    w.Start()
    For i = 1 To kITER
      o.Bar = i.ToString()
    Next
    w.Stop()
    Console.WriteLine(w.Elapsed)

    Console.Write(vbCrLf & "Done. Press a key")
    Console.ReadKey()
  End Sub

End Module